"Who is in charge of price action?"

{Cmacdon Note: This Traffic Light indicator is amalgamation of 5 ways to interpret who is in charge of the market}

{Choose}

Ch := input("1=Body 2=TW 3=LW 4=Torque 5=HAbody",5,1);

{Exponential MA period}

pd := input("MA Time periods",3,1);

{1=Candle Body interpretation of net Smart Money.  On assumption wicks are downward tests or upthrust testing within a bar}

Body:=(C-O);

{2=Tom Williams basis for identifying a trend interpretation across tqo bars}

TW:=Close-Hist(C,1);

{3=Larry Williams approach to net Smart Money within a bar}

LW:=((C-L)-(H-C)); 

{4=Torque approach to net Smart Money (see earlier post for reference to William C Garret Work}

Value1a := If(H>=Hist(C,1),- (H-L), H-Hist(c,1)-(H-L)); {Price movement representing Selling Vol}

Value2 := If(H>=Hist(C,1),(H-Hist(c,1) + (C-L)), (C-L)) ; {Price movement representing Buying Vol}

Torque:=(Value1a+Value2);

{5=Heikin Ashi Aprroach to Candle Body Size}

haClose := (O+H+L+C)/4;

haOpen := (prev + hist(haClose,1))/2;

HAbody:=(haClose-haOpen);

TrafficLight:=(if(ch=1,Body, if(ch=2, TW, if(ch=3,LW, if(ch=4,Torque,HAbody)))));

Greenlight:=Ma(TrafficLight,Pd,Exponential);

[name=Green Traffic Lights1; linestyle=Solid; width=2] [color=Black; name=Greenlight]

Greenlight;

[Linestyle=Solid; Color=black;]

d:=0;

d;

[linestyle=fill; color=Green;]Greenlight;

[linestyle=fill; color=RED;]d;

[name=Green Traffic Lights Go; linestyle=bar; width=4] [color=Green;]

If(Greenlight>=0,Greenlight,undefined);

[name=Traffic Lights Warning; linestyle=bar; width=4] [color=Orange;]

If(Greenlight>=0 AND Greenlight<Hist(Greenlight,1),Greenlight,undefined);

[name=Red Traffic Lights; linestyle=bar; width=4] [color=Red;]

If(Greenlight<0,Greenlight,undefined);

[name=Red Traffic Lights Get ready; linestyle=bar; width=4] [color=Lime Green;]

If(Greenlight<0 AND Greenlight>Hist(Greenlight,1),Greenlight,undefined);