Insync Index Indicator

InSync Index - Consensus Trading Indicator

 

The InSync Index is a consensus oscillator created in 1995 by Norm North. A consensus oscillator is an indicator that generates an output using the value of many other trading indicators.

The InSync Index is calculated by summing several technical analysis indicators including the Bollinger Bands, Moving average convergence/divergence, Commodity channel index, Relative Strength Index, Rate of change, Stochastic, Detrended Price Oscillator, Ease of movement and Money flow index.

Each trading indicator is compared to specific thresholds and a value of -5, 0 or +5 is then added to the InSync Index. The Relative Strength Index for example is compared to 70 and 30 levels. If RSI is higher than 70 then a value of 5 is added to the InSync Index. If its value is lower than 30 then a value of 5 is removed from the InSync Index, otherwise the InSync Index is unchanged and in this case, theRSI indicator do not contribute to the InSync Index.

The InSync Index can be used in the watchlist and screener tools to detect extreme levels. Values higher or equal to 80 are considered to be high extreme levels, while values lower or equal than 20 are considered to be low extreme levels. When an extreme level is reached, the InSync Index should be confirmed by another indicator (fundamental, options-based or another indicator not already used in the InSync Index calculation) or a candlestick pattern.
This trading indicator works well in ranging markets and shouldn't be applied in trending markets.

The InSync Index function name is "InSync". The indicator requires no parameters.

INSYNC Index

The formula from Equis: Insync Index (rev. 01/06/97)

The interpretation for the following formulas came from the article "The Insync Index", by Norm North, in Technical Analysis of Stocks & Commodities Jan 1995. 

All of these formulas are necessary for the last one, Insync Index to run properly. They are listed in the order in which they should be copied and pasted into the MetaStock Formula Builder


BOLInSLB 
Mov( C ,20 ,S ) - 2 * ( Std( C ,20 ) )

BOLInSUB 
Mov( C ,20 ,S ) + 2 * ( Std( C ,20 ) )

BOLInS2 
( C - Fml( "BOLInSLB" ) ) / ( Fml( "BOLInSUB" ) - Fml( "BOLInSLB" ) )

BOLInSLL 
If( Fml( "BOLInS2" ) ,< , .05 ,-5 ,If( Fml( "BOLInS2" ) ,> ,.95 ,5 ,0 ) )

CCIInS 
If( CCI(14 ) ,> ,100 ,5 ,If ( CCI(14 ) ,< ,-100 ,-5 ,0 ) )

EMVInS2 
EMV(10 ,S ) - Mov( EMV(10 ,S) ,10 ,S )

EMVInSB 
If( Fml( "EMVInS2" ) ,< ,0 ,If( Mov( EMV(10 ,S ) ,10 ,S ) ,< ,0 ,-5 ,0 ) ,0 )

EMVInSS 
If( Fml( "EMVInS2" ) ,> ,0 ,If( Mov( EMV(10 ,S ) ,10 ,S ) ,> ,0 ,5 ,0 ) ,0 )

MACDInS2 
MACD( ) - Mov( MACD( ) ,10 ,S )

MACDinSB 
If( Fml( "MACDInS2" ) ,< ,0 ,If( Mov( MACD( ) ,10 ,S ) ,< ,0 ,-5 ,0 ) ,0 )

MACDInSS 
If( Fml( "MACDInS2" ) ,> ,0 ,If( Mov( MACD( ) ,10 ,S) ,> ,0 ,5 ,0 ) ,0 )

MFIInS 
If( MFI( 20 ) ,> ,80 ,5 , If( MFI( 20 ) ,< ,20 ,-5 ,0 ) )

PDOInS2 
DPO( 18 ) - Mov( DPO( 18 ) ,10 ,S )

PDOInSB 
If( Fml( "PDOInS2" ) ,< ,0 ,If( Mov( DPO( 18 ) ,10 , S) ,< ,0 ,-5 ,0 ) ,0 )

PDOInSS 
If( Fml( "PDOInS2" ) ,> ,0 ,If( Mov( DPO ( 18 ) ,10 ,S) ,> ,0 ,5 ,0 ) ,0 )

ROCInS2 
ROC( C ,10 ,$ ) - Mov( ROC( C ,10 ,$ ) ,10 ,S )

ROCInSB 
If( Fml( "ROCInS2" ) ,< ,0 ,If( Mov( ROC( C ,10 ,$ ) ,10 ,S ) ,< ,0 ,-5 ,0 ) ,0 )

ROCInSS Index 
If( Fml( "ROCInS2" ) ,> ,0 ,If( Mov( ROC( C ,10 ,$ ) ,10 ,S ) ,> ,0 ,5 ,0 ) ,0 )

RSIInS 
If( RSI(14 ) ,> ,70 ,5 ,If( RSI(14 ), < ,30 ,-5 ,0 ) )

STO%dInS 
If( Stoch(14 ,3 ) ,> ,80 ,5 ,If( Stoch(14 ,3 ) ,< ,20 ,-5 ,0 ) )

STO%kInS 
If( Stoch(14 ,1) ,> ,80 ,5 ,If( Stoch(14 ,1 ) ,< ,20 ,-5 ,0 ) )

InSync Index 
50 + Fml( "CCIInS" ) + Fml( "BOLInSLL" ) + Fml( "RSIInS" ) + Fml( "STO%kInS " ) +
Fml( "STO%dInS" ) + Fml( "MFIInS" ) + Fml( "EMVInSB" ) + Fml( "EMVInSS" ) + 
Fml( "ROCInSS" ) + Fml( "ROCInSB" ) + Ref (Fml( "PDOInSS" ) ,-10 ) + 
Ref (Fml( "PDOInSB" ) ,-10 ) + Fml( "MACDInS S" ) + Fml( "MACDInSB" )