Channel Indicator

[Description="Averaged Weekly 50% Pivot"]

method := inputma("Method",E);

tp:=Input("Period",6,2);

sigs:=input("Signals 1=on 0=off",1,0,1);

wp:=input("Weekly Pivot 1=on 0=off",0,0,1);

[target=price]

m:=Month()<>Ref(Month(),-1);

p:=ValueWhen(1,DayOfWeek()=1 or m,ref(HHV(H,5)+LLV(L,5),-1)/2);

[linestyle=solid; color=orchid]

if(wp,p,undefined); {weekly pivot point 50%}

[linestyle=solid; color=medium slate blue]

pa:=ma(ref(HHV(H,tp)+LLV(L,tp),-1)/2,tp,method); {pivot averaged}

SignalLong := if(sigs AND C>=pa AND hist(C,1)>hist(pa,1) AND hist(C,2)<hist(pa,2),1,0);

SignalShort := if(sigs AND C<pa AND hist(C,1)<hist(pa,1) AND hist(C,2)>=hist(pa,2),1,0);

SigLong := if(SignalLong,1,if(SignalShort,0,prev));

SigShort := if(SignalShort,1,if(SignalLong,0,prev));

[linestyle=marker; marker=long; name=""]

If(SigLong and SigLong <> hist(SigLong,1),1,0);

[linestyle=marker; marker=short; name=""]

If(SigShort and SigShort <> hist(SigShort,1),1,0);

[linestyle=pricecolor]

[color=rgb(98,217,98)] {lime green}

If(C>=pa,1,0);

[color=rgb(226,118,118)] {red}

If(C<pa,1,0);

LE:=If(SigLong and SigLong <> hist(SigLong,1), C, prev); { LE price save }

SE:=If(SigShort and SigShort <> hist(SigShort,1), C, prev); { SE price save }

LEp:=If(SigLong and SigLong <> hist(SigLong,1), round(((SE-LE)/SE)*100,2), undefined);

SEp:=If(SigShort and SigShort <> hist(SigShort,1), round(((SE-LE)/LE)*100,2), undefined);

[color=Forest Green]

[linestyle=Text; textalign=Above,Center]

If(LEp>=0, "+" + LEp + "%", undefined);

High;

[color=Forest Green]

[linestyle=Text; textalign=Below,Center]

If(SEp>0, "+" + SEp + "%", undefined);

Low;

[color=Crimson]

[linestyle=Text; textalign=Below,Center]

If(SEp<0, " " + SEp + "%", undefined);

Low;

[color=Crimson]

[linestyle=Text; textalign=Above,Center]

If(LEp<0, " " + LEp + "%", undefined);

High;